mirror of
https://github.com/PabloMK7/citra.git
synced 2024-11-19 22:16:36 +00:00
4a590d1fcb
xbyak is intended to be installed in /usr/local/include/xbyak. Since we desire not to install xbyak before using it, we copy the headers to the appropriate directory structure and use that instead Co-authored-by: merry <git@mary.rs>
155 lines
4.4 KiB
CMake
Vendored
155 lines
4.4 KiB
CMake
Vendored
# Definitions for all external bundled libraries
|
|
|
|
# Suppress warnings from external libraries
|
|
if (CMAKE_CXX_COMPILER_ID MATCHES "MSVC")
|
|
add_compile_options(/W0)
|
|
endif()
|
|
|
|
set(CMAKE_MODULE_PATH ${CMAKE_MODULE_PATH} ${PROJECT_SOURCE_DIR}/CMakeModules)
|
|
include(DownloadExternals)
|
|
include(ExternalProject)
|
|
|
|
# Boost
|
|
set(BOOST_ROOT "${CMAKE_SOURCE_DIR}/externals/boost")
|
|
set(Boost_INCLUDE_DIR "${CMAKE_SOURCE_DIR}/externals/boost")
|
|
set(Boost_NO_SYSTEM_PATHS ON)
|
|
add_library(boost INTERFACE)
|
|
target_include_directories(boost SYSTEM INTERFACE ${Boost_INCLUDE_DIR})
|
|
|
|
# Boost::serialization
|
|
file(GLOB boost_serialization_SRC "${CMAKE_SOURCE_DIR}/externals/boost/libs/serialization/src/*.cpp")
|
|
add_library(boost_serialization STATIC ${boost_serialization_SRC})
|
|
target_link_libraries(boost_serialization PUBLIC boost)
|
|
|
|
# Add additional boost libs here; remember to ALIAS them in the root CMakeLists!
|
|
|
|
# Catch2
|
|
set(CATCH_INSTALL_DOCS OFF)
|
|
set(CATCH_INSTALL_EXTRAS OFF)
|
|
add_subdirectory(catch2)
|
|
|
|
# Crypto++
|
|
add_subdirectory(cryptopp)
|
|
|
|
# Xbyak
|
|
if (ARCHITECTURE_x86_64)
|
|
add_library(xbyak INTERFACE)
|
|
file(MAKE_DIRECTORY ${CMAKE_CURRENT_BINARY_DIR}/xbyak/include)
|
|
file(COPY ${CMAKE_CURRENT_SOURCE_DIR}/xbyak/xbyak DESTINATION ${CMAKE_CURRENT_BINARY_DIR}/xbyak/include)
|
|
target_include_directories(xbyak SYSTEM INTERFACE ${CMAKE_CURRENT_BINARY_DIR}/xbyak/include)
|
|
target_compile_definitions(xbyak INTERFACE XBYAK_NO_OP_NAMES)
|
|
endif()
|
|
|
|
# Dynarmic
|
|
if (ARCHITECTURE_x86_64 OR ARCHITECTURE_ARM64)
|
|
set(DYNARMIC_TESTS OFF)
|
|
set(DYNARMIC_NO_BUNDLED_FMT ON)
|
|
set(DYNARMIC_FRONTENDS "A32")
|
|
add_subdirectory(dynarmic)
|
|
endif()
|
|
|
|
# libfmt
|
|
add_subdirectory(fmt)
|
|
|
|
# getopt
|
|
if (MSVC)
|
|
add_subdirectory(getopt)
|
|
endif()
|
|
|
|
# Glad
|
|
add_subdirectory(glad)
|
|
|
|
# inih
|
|
add_subdirectory(inih)
|
|
|
|
# MicroProfile
|
|
add_library(microprofile INTERFACE)
|
|
target_include_directories(microprofile INTERFACE ./microprofile)
|
|
|
|
# Nihstro
|
|
add_library(nihstro-headers INTERFACE)
|
|
target_include_directories(nihstro-headers INTERFACE ./nihstro/include)
|
|
|
|
# Open Source Archives
|
|
add_subdirectory(open_source_archives)
|
|
|
|
# SoundTouch
|
|
add_subdirectory(soundtouch)
|
|
# The SoundTouch target doesn't export the necessary include paths as properties by default
|
|
target_include_directories(SoundTouch INTERFACE ./soundtouch/include)
|
|
|
|
# Teakra
|
|
add_subdirectory(teakra EXCLUDE_FROM_ALL)
|
|
|
|
# SDL2
|
|
if (ENABLE_SDL2 AND NOT USE_SYSTEM_SDL2)
|
|
add_subdirectory(sdl2)
|
|
endif()
|
|
|
|
# Zstandard
|
|
set(ZSTD_LEGACY_SUPPORT OFF)
|
|
set(ZSTD_BUILD_PROGRAMS OFF)
|
|
set(ZSTD_BUILD_SHARED OFF)
|
|
add_subdirectory(zstd/build/cmake EXCLUDE_FROM_ALL)
|
|
target_include_directories(libzstd_static INTERFACE $<BUILD_INTERFACE:${CMAKE_SOURCE_DIR}/externals/zstd/lib>)
|
|
|
|
# ENet
|
|
add_subdirectory(enet)
|
|
target_include_directories(enet INTERFACE ./enet/include)
|
|
|
|
# Cubeb
|
|
if (ENABLE_CUBEB)
|
|
set(BUILD_TESTS OFF CACHE BOOL "")
|
|
add_subdirectory(cubeb EXCLUDE_FROM_ALL)
|
|
endif()
|
|
|
|
# DiscordRPC
|
|
if (USE_DISCORD_PRESENCE)
|
|
add_subdirectory(discord-rpc EXCLUDE_FROM_ALL)
|
|
target_include_directories(discord-rpc INTERFACE ./discord-rpc/include)
|
|
endif()
|
|
|
|
if (ENABLE_WEB_SERVICE)
|
|
find_package(OpenSSL 1.1)
|
|
if (OPENSSL_FOUND)
|
|
set(OPENSSL_LIBRARIES OpenSSL::SSL OpenSSL::Crypto)
|
|
else()
|
|
# LibreSSL
|
|
set(LIBRESSL_SKIP_INSTALL ON CACHE BOOL "")
|
|
set(OPENSSLDIR "/etc/ssl/")
|
|
add_subdirectory(libressl EXCLUDE_FROM_ALL)
|
|
target_include_directories(ssl INTERFACE ./libressl/include)
|
|
target_compile_definitions(ssl PRIVATE -DHAVE_INET_NTOP)
|
|
get_directory_property(OPENSSL_LIBRARIES
|
|
DIRECTORY libressl
|
|
DEFINITION OPENSSL_LIBS)
|
|
endif()
|
|
# JSON
|
|
add_library(json-headers INTERFACE)
|
|
target_include_directories(json-headers INTERFACE ./json)
|
|
|
|
if(ANDROID)
|
|
add_subdirectory(android-ifaddrs)
|
|
endif()
|
|
|
|
# httplib
|
|
add_library(httplib INTERFACE)
|
|
target_include_directories(httplib INTERFACE ./httplib)
|
|
target_compile_options(httplib INTERFACE -DCPPHTTPLIB_OPENSSL_SUPPORT)
|
|
target_link_libraries(httplib INTERFACE ${OPENSSL_LIBRARIES})
|
|
|
|
# cpp-jwt
|
|
add_library(cpp-jwt INTERFACE)
|
|
target_include_directories(cpp-jwt INTERFACE ./cpp-jwt/include)
|
|
target_compile_definitions(cpp-jwt INTERFACE CPP_JWT_USE_VENDORED_NLOHMANN_JSON)
|
|
endif()
|
|
|
|
# lodepng
|
|
add_subdirectory(lodepng)
|
|
|
|
# (xperia64): Only use libyuv on Android b/c of build issues on Windows and mandatory JPEG
|
|
if(ANDROID)
|
|
# libyuv
|
|
add_subdirectory(libyuv)
|
|
target_include_directories(yuv INTERFACE ./libyuv/include)
|
|
endif()
|